Visibility of content controls

I have a Word document (aaa.docm) that contains two content controls. The first is a drop-down list content control (Title: CCDDL) with the selections "No issues" and "Issues found". The second is a text box content control (Title: CCTB) to be used to describe the "Issue". I would like the Content Control Text Box to disappear if "No issues" is selected from the drop-down list.  When I use the below VB code, the Content Control Text Box will disappear if I select "No Issue" but it will not reappear if I select "Issues found".  What am i doing wrong?

Code:

---

Sub UpdateTextBoxVisibility()
    Dim ddValue As String
    ddValue = ActiveDocument.SelectContentControlsByTitle("CDDL")(1).DropdownListEntries(1).Value
    If ddValue = "No issues" Then
        ActiveDocument.SelectContentControlsByTitle("CCTB")(1).Range.Font.Hidden = True
    Else
        ActiveDocument.SelectContentControlsByTitle("CCTB")(1).Range.Font.Hidden = False
    End If
End Sub

---

Thanks for your help!

Welcome to VBAX New@VB

Try changing the logic around

Code:

---

Sub UpdateTextBoxVisibility()
    Dim ddValue As String
    ddValue = ActiveDocument.SelectContentControlsByTitle("CDDL")(1).DropdownListEntries(1).Value
    If ddValue <> "No issues" Then
        ActiveDocument.SelectContentControlsByTitle("CCTB")(1).Range.Font.Hidden = False
    Else
        ActiveDocument.SelectContentControlsByTitle("CCTB")(1).Range.Font.Hidden = True
    End If
End Sub

---

content controls don't have events of their own.

Aussiebear - Thanks... I tried as you suggested but still can't get it to work.
arnelg - thanks... but i don't understand what you mean by content controls don't have events of their own. Is there additional code that i need to add to have it function?

I noticed in your code you had used 'CDDL' as the name, however, you stated that the name was 'CCDDL'.
Secondly, from my understanding 'DropdownListEntries(1).Value' will always be the same value as it is just the first item in the list.

The below code will fire when you change the CCDDL value and exit the content control:

Code:

---

Private Sub Document_ContentControlOnExit(ByVal ContentControl As ContentControl, Cancel As Boolean)
    Dim ddValue As String
    ddValue = ActiveDocument.SelectContentControlsByTitle("CCDDL")(1).Range.Text
   
    If ddValue = "No issues" Then
        ActiveDocument.SelectContentControlsByTitle("CCTB")(1).Range.Font.Hidden = True
    Else
        ActiveDocument.SelectContentControlsByTitle("CCTB")(1).Range.Font.Hidden = False
    End If
End Sub

---

Code:

---

Sub UpdateTextBoxVisibility()
  If ActiveDocument.SelectContentControlsByTitle("CCDDL")(1).Range.Text = "Issues" Then
    ActiveDocument.SelectContentControlsByTitle("CCTB")(1).Range.Font.Hidden = False
  Else
    ActiveDocument.SelectContentControlsByTitle("CCTB")(1).Range.Font.Hidden = True
  End If
End Sub

---

Still doesn't work. I must be still be doing something wrong. I've started an new file that only contains these some basic text and these two content controls. The file was saved as a .docm

Drop down options in CCDDL are: "Issues found" and "No issues".

Code:

---

Sub UpdateTextBoxVisibility()
    If ActiveDocument.SelectContentControlsByTitle("CCDDL")(1).Range.Text = "Issues found" Then
        ActiveDocument.SelectContentControlsByTitle("CCTB")(1).Range.Font.Hidden = False
    Else
        ActiveDocument.SelectContentControlsByTitle("CCTB")(1).Range.Font.Hidden = True
    End If
End Sub

---

Also, should the code be entered into the "Module" or "Class Module" window?
Thanks!!!
Paul.

In a Worksheet Module

I cant find "Worksheet Module". FYI - I'm using this in a Word document.

My apologies. Document Module.

Can you post your sample document. There is nothing wrong with your code. What is calling your code?

How do I post my document?
Thanks!

Same as you have created the post above except click 'Go Advanced'. Then you can see the last link in my signature below which should show you the rest.

Attached is the sample file that I am having problems with configuring: 1) visibility of a textbox content control based on the selection from a content control dropdown; and, 2) to change the color of the font based on the dropdown menu.
Your assistance is greatly appreciated!
I have learned a lot already! Thanks!

I didn't see anywhere that you were calling the code to set your visibility. "Hidden" text is a poor method, because some people like to show hidden text in documents. Put this is the ThisDocument module:

Code:

---

Private Sub Document_ContentControlOnExit(ByVal CCtrl As ContentControl, Cancel As Boolean)
    If CCtrl.Title = "CCDDL" Then
          With CCtrl.Range
              Select Case .Text
                  Case "Issues found"
                    .Font.ColorIndex = wdRed
                  Case Else
                      .Font.ColorIndex = wdBlack
              End Select
          End With
        'UpdateTextBoxVisibilityI
        'Or
        'UpdateTextBoxVisibilityII
        'Or
      UpdateTextBoxVisibilityIII
    End If
End Sub

Sub UpdateTextBoxVisibilityI()
    If ActiveDocument.SelectContentControlsByTitle("CCDDL")(1).Range.Text = "Issues found" Then
        ActiveDocument.SelectContentControlsByTitle("CCTB")(1).Range.Font.Hidden = False
    Else
        ActiveDocument.SelectContentControlsByTitle("CCTB")(1).Range.Font.Hidden = True
        'Note: if you or your users has File>Options>Display>Show Hidden Text checked then you will see the text with a dotted line under it.
        'You might want to use as white font, or set the placeholder text to a zero length string.
    End If
End Sub

Sub UpdateTextBoxVisibilityII()
    If ActiveDocument.SelectContentControlsByTitle("CCDDL")(1).Range.Text = "Issues found" Then
        ActiveDocument.SelectContentControlsByTitle("CCTB")(1).Range.Font.ColorIndex = wdBlack
    Else
        ActiveDocument.SelectContentControlsByTitle("CCTB")(1).Range.Font.ColorIndex = wdWhite
    End If
End Sub

Sub UpdateTextBoxVisibilityIII()
    If ActiveDocument.SelectContentControlsByTitle("CCDDL")(1).Range.Text = "Issues found" Then
        ActiveDocument.SelectContentControlsByTitle("CCTB")(1).SetPlaceholderText , , "Enter issues here"
    Else
        ActiveDocument.SelectContentControlsByTitle("CCTB")(1).SetPlaceholderText , , ChrW(8203)
        ActiveDocument.SelectContentControlsByTitle("CCTB")(1).Range.Text = vbNullString
    End If
End Sub

---

Solved
Fantastic!!! I like the "UpdateTextBoxVisibilityIII" the best!
Thanks for all that helped. I continue to learn and having fun!
Cheers!

So if you wished, you could simply use:

Code:

---

Private Sub Document_ContentControlOnExit(ByVal CCtrl As ContentControl, Cancel As Boolean)
  If CCtrl.Title = "CCDDL" Then
    With CCtrl.Range
      Select Case .Text
          Case "Issues found"
            .Font.ColorIndex = wdRed
            ActiveDocument.SelectContentControlsByTitle("CCTB")(1).SetPlaceholderText , , "Enter issues here"
          Case Else
            .Font.ColorIndex = wdBlack
            ActiveDocument.SelectContentControlsByTitle("CCTB")(1).SetPlaceholderText , , ChrW(8203)
            ActiveDocument.SelectContentControlsByTitle("CCTB")(1).Range.Text = vbNullString
      End Select
    End With
  End If
End Sub

---

Even better! I'll use this. I've posted another issue in a separate thread: why I can't get this code to work for similar CCtls with different names.
Thanks again!