Option Explicit 
 
 
Sub RemoveConditionalFormats_Macro() 
     'The Macro is to provide Menu access to the main function.
     'It is also the example for the main function's usage
     '
     ' As a Macro, it assumes that IF the User has NOT selected more
     ' than one Cell, THEN the User wants to clear the entire active sheet.
     '
     'In-Code comments apply to the Usage of the main function
     
    Dim Result As Boolean 
    Dim Rng As Range 
    Dim ShtName As String 
     
     ''''Assign a Sheet to use
    ShtName = ActiveSheet.Name 
     ' Alternately
     'ShtName = "SomeSheetName"
     
     ''''Assign a Range to clear
    Set Rng = Selection 
     ' Alternately:
     'Set Rng = Range("A1:B25")
     ' Alternately:
     'Set Rng = Code that returns a Range
     
     'For this macro only
    If Rng.Count = 1 Then Set Rng = ActiveSheet.UsedRange 
     
     ''''Call the function
     'If no parameters were supplied, the main function would clear
     ' the entire active sheet.
    Result = RemoveConditionalFormats(ShtName, Rng) 
     
     ''''Test For success
    If Result = True Then 
         'Either found no FormatConditions or successfully removed all of them
    Else 
         'Problem, check your code.
    End If 
End Sub 
 
 
Function RemoveConditionalFormats(Optional SheetName As String = "", _ 
    Optional RangeToClear As Range = Nothing) _ 
    As Boolean 
     'Will return FALSE on any error.
     'Returns TRUE if no FormatConditions found or if all desired were
     ' successfully removed.
     'The Default is to clear the entire ActiveSheet
     'The Coder can specify which sheet and Cell(s) to clear.
     ' See Sub RemoveConditionalFormats_Macro above for example of usage.
     
    Dim FCondition As FormatCondition 
    Dim Cel As Range 
    Dim i As Long 
    Dim Rng As Range 
    Dim Sht As Worksheet 
     
     ''''Insure proper Initialization. Always Be Sure, (ABS Motto!)
     'ABS is not recommended where speed is crucial.
    RemoveConditionalFormats = False 
     
     ''''Minimal Error Handling.
    On Error GoTo TheresAProblem 
     
     ''''Turn off screen updates to improve performance
    Application.ScreenUpdating = False 
     
     ''''Determine Worksheet and Range to use.
    If SheetName = "" Then 'The SheetName arg was not supplied
        Set Sht = ActiveSheet 
    Else 'Use the arg as supplied
        Set Sht = Sheets(SheetName) 
    End If 
    Set Rng = RangeToClear 
    If Rng Is Nothing Then 'The RangeToClear arg was not supplied
        Set Rng = Sht.UsedRange ' therefore, clear the Entire sheet
    End If 
     
     ''''Remove each FormatCondition Object from each Cell in the desired Range.
    For Each Cel In Rng 
         'Check if the Cell has any FormatCondition Objects.
        If Cel.FormatConditions.Count > 0 Then 
             'Index backwards because Collection.Count changes with each deletion. (ABS)
            For i = Cel.FormatConditions.Count To 1 Step -1 
                Cel.FormatConditions(i).Delete 
            Next i 
        End If 
    Next Cel 
     
     ''''Operation finished with no problems
     ''''Turn screen updates back on
    Application.ScreenUpdating = True 
     
     ''''Set the function's return value to show success
    RemoveConditionalFormats = True 
    Exit Function 
     
TheresAProblem: 
     ''''Turn screen updates back on. (ABS)
    Application.ScreenUpdating = True 
     
     ''''An Error occured. Set the Function's return value to False.
     'Leave some clue for the coder, do NOT Zero out the Error.
    RemoveConditionalFormats = False 
End Function