'<< CODE FOR THE "ThisWorkbook" MODULE     >>
 
 '<< NOTE THAT SCREEN HEIGHT & WIDTH ARE   >>
 '<< MEASURED IN PIXELS, WHILE APPLICATION >>
 '<< & WINDOW HEIGHTS AND WIDTHS ARE       >>
 '<< MEASURED IN POINTS. (pixel ~ 3/4 point)   >>
Option Explicit 
 
Private Sub Workbook_Open() 
     
     'N.B. a screen resolution of 800x600 pixels was used for this E.G.
     
     '//Obtain current users screen width & height (in pixels)
    Run ("MonitorInfo") 
     
    With Application 
         'cancel any xlMaximized
        .WindowState = xlNormal 
         
         '<<Set values for the application window>>
         '//POSITION WITH RESPECT TO MONITOR
        .Top = 1 '< points
        .Left = 1 '< points
         
         '//WIDTH
         'replace 400 with the width you want
         'replace 800 with your screen width
        .Width = 400 * ScrWidth / 800 
         
         '//HEIGHT
         'replace 300 with the height you want
         'replace 600 with your screen height
        .Height = 300 * ScrHeight / 600 
         
        With .ActiveWindow 
             'cancel any xlMaximized
            .WindowState = xlNormal 
             
             '<<Set values for the book inside the application>>
             '//POSITION WITH RESPECT TO APP. WINDOW
            .Top = 1 '< points
            .Left = 1 '< points
             
             'ZOOM
             'replace 800 with your screen width
            .Zoom = 100 * ScrWidth / 800 '< 100 is %
             
             'WIDTH
             'replace Application.UsableWidth
             'with a number for the width you want
            .Width = Application.UsableWidth 
             
             'HEIGHT
             'replace Application.UsableHeight
             'with a number for the height you want
            .Height = Application.UsableHeight 
             
        End With 
    End With 
End Sub 
 
 
 
 
 
 '<< CODE FOR THE STANDARD MODULE >>
 
Option Explicit 
Public ScrWidth&, ScrHeight& 
Declare Function GetSystemMetrics32 Lib "User32" _ 
Alias "GetSystemMetrics" (ByVal nIndex&) As Long 
 
Private Sub MonitorInfo() 
    ScrWidth = GetSystemMetrics32(0) '< in pixels
    ScrHeight = GetSystemMetrics32(1) 
End Sub