'WRAPPING SUB EXAMPLE 1
 'Clear all contents of cells containing a specific substring. The sub bellow uses FindAll:
Public Sub BlankCellsContainingString() 
    Dim RgToSearch As Range 'Range to search
    Dim CharToFind As String 'String to find
    Dim rg As Range 
     
     '------ CHANGE HERE ------
    Set RgToSearch = ActiveSheet.Range("A:A") 'Search in A:A
    CharToFind = ">" 'search for the '>' character
     '-------------------------
    Set rg = FindAll(CharToFind, RgToSearch, xlValues, xlPart) 
    If Not rg Is Nothing Then 
        rg.ClearContents 'clear result range
    End If 
End Sub 
 
 'WRAPPING SUB - EXAMPLE 2
 'Search cells in column A of value 'HI' in uppercase only. Copy their entire row at the end
 'of the current data in sheet 2.
Sub CopyCellsContainingString() 
    Dim RgToSearch As Range 
    Dim CharToFind As String 
    Dim RgDestination As Range 
    Dim rg As Range 
     
     '------ change here ------
    Set RgToSearch = ActiveSheet.Range("A:A") 'search in A:A
    CharToFind = "HI" 'Search for HI
    Set RgDestination = ActiveWorkbook.Worksheets(2).Range("A65536") _ 
    .End(xlUp).Offset(1, 0).EntireRow 
     '-------------------------
     
    Set rg = FindAll(CharToFind, RgToSearch, xlValues, xlWhole, True, False) 
    If Not rg Is Nothing Then 
        rg.EntireRow.Copy RgDestination 'copy resulting rows in RgDestination
    End If 
End Sub 
 
 '---------------------------------------------------------------------------------------------------------------------
 'FUNCTION FINDALL : Find all macthing cells and return them into one single range.
 '      What:     what to search for
 '      Where:  range to search
 '      LookIn:  look into xlComments, xlFormulas, or xlValues (default)
 '      LookAt:   look at xlPart (default) or xlWhole
 '      MatchCase:   True or False (default)
 '      MatchByte:      True or False (default)
 ' Assumes: neither What or Where is Nothing.
Public Function FindAll( _ 
    What As Variant, _ 
    Where As Range, _ 
    Optional LookIn As XlFindLookIn = xlValues, _ 
    Optional LookAt As XlLookAt = xlPart, _ 
    Optional MatchCase As Boolean = False, _ 
    Optional MatchByte As Boolean = False) As Range 
     ' 2002 - Sebastien Mistouflet
    Dim ResultRg  As Range 
    Dim rg As Range 
    Dim firstAddress As String 
     
    With Where 
        Set rg = .Find(What, LookIn:=LookIn, LookAt:=LookAt, _ 
        MatchCase:=MatchCase, MatchByte:=MatchByte) 
        If Not rg Is Nothing Then 
            Set ResultRg = rg 
            firstAddress = rg.Address 
            Do 
                Set ResultRg = Application.Union(ResultRg, rg) 
                Set rg = .FindNext(rg) 
            Loop While Not rg Is Nothing And rg.Address <> firstAddress 
        End If 
    End With 
     
    Set FindAll = ResultRg 'Range to return
End Function 
 '-------------------------------------------------------------------------------------------------------------