Option Explicit 
 
Sub Formatting() 
     
    Dim WS              As Worksheet 
    Dim RngConstants    As Range 
    Dim RngFormulas     As Range 
    Dim RngCell         As Range 
     
    For Each WS In Worksheets 
        With WS.Cells 
             'Remove borders
            .Borders.LineStyle = xlNone 
             
             'Remove color fills
            .Interior.ColorIndex = xlNone 
             
             'Change the Row Height and Column Width
            .RowHeight = 12.75 
            .ColumnWidth = 8.43 
             
             'Change several Font properties
            With .Font 
                .ColorIndex = 0 
                .Bold = False 
                .Italic = False 
                .Underline = False 
                .Name = "Arial" 
                .Size = 10 
            End With 
        End With 
        With WS 
             
             'Change the format of all dates to mm/dd/yy
             
             'Narrow the range we are looping through
            On Error Resume Next 
            Set RngConstants = .Cells.SpecialCells(xlCellTypeConstants, 1) 
            Set RngFormulas = .Cells.SpecialCells(xlCellTypeFormulas, 1) 
            On Error GoTo 0 
             
             'Loop through cells with constants
            If Not RngConstants Is Nothing Then 
                For Each RngCell In RngConstants 
                    If IsDate(RngCell.Value) Then 
                        .Range(RngCell.Address).NumberFormat = "mm/dd/yy;@" 
                    End If 
                Next 
            End If 
             
             'Loop through cells with formulas
            If Not RngFormulas Is Nothing Then 
                For Each RngCell In RngFormulas 
                    If IsDate(RngCell.Value) Then 
                        .Range(RngCell.Address).NumberFormat = "mm/dd/yy;@" 
                    End If 
                Next 
            End If 
        End With 
    Next 
     
End Sub