'Place this code in a Module
 
Option Compare Text 
Option Explicit 
 
Public Path         As String 
 
Private Const BIF_RETURNONLYFSDIRS As Long = &H1 
Private Const BIF_DONTGOBELOWDOMAIN As Long = &H2 
Private Const BIF_RETURNFSANCESTORS As Long = &H8 
Private Const BIF_BROWSEFORCOMPUTER As Long = &H1000 
Private Const BIF_BROWSEFORPRINTER As Long = &H2000 
Private Const BIF_BROWSEINCLUDEFILES As Long = &H4000 
Private Const MAX_PATH As Long = 260 
 
Type BrowseInfo 
    hOwner As Long 
    pidlRoot As Long 
    pszDisplayName As String 
    lpszINSTRUCTIONS As String 
    ulFlags As Long 
    lpfn As Long 
    lParam As Long 
    iImage As Long 
End Type 
 
Type SHFILEOPSTRUCT 
    hwnd As Long 
    wFunc As Long 
    pFrom As String 
    pTo As String 
    fFlags As Integer 
    fAnyOperationsAborted As Boolean 
    hNameMappings As Long 
    lpszProgressTitle As String 
End Type 
 
Declare Function SHGetPathFromIDListA Lib "shell32.dll" ( _ 
ByVal pidl As Long, _ 
ByVal pszBuffer As String) As Long 
Declare Function SHBrowseForFolderA Lib "shell32.dll" ( _ 
lpBrowseInfo As BrowseInfo) As Long 
 
Function BrowseFolder(Optional Caption As String = "") As String 
     
    Dim BrowseInfo As BrowseInfo 
    Dim FolderName As String 
    Dim ID As Long 
    Dim Res As Long 
     
    With BrowseInfo 
        .hOwner = 0 
        .pidlRoot = 0 
        .pszDisplayName = String$(MAX_PATH, vbNullChar) 
        .lpszINSTRUCTIONS = Caption 
        .ulFlags = BIF_RETURNONLYFSDIRS 
        .lpfn = 0 
    End With 
    FolderName = String$(MAX_PATH, vbNullChar) 
    ID = SHBrowseForFolderA(BrowseInfo) 
    If ID Then 
        Res = SHGetPathFromIDListA(ID, FolderName) 
        If Res Then 
            BrowseFolder = Left$(FolderName, InStr(FolderName, _ 
            vbNullChar) - 1) 
        End If 
    End If 
     
End Function 
 
Sub ShowFiles() 
     
    Dim FileName        As String 
     
    Load UserForm1 
    With UserForm1 
        Path = BrowseFolder 
        FileName = Dir(Path & "\*.xls", vbNormal) 
        Do Until FileName = "" 
            If Left(FileName, 3) = "MRR" Then 
                .ListBox1.AddItem (FileName) 
            End If 
            FileName = Dir() 
        Loop 
        .Show 
    End With 
     
End Sub 
 
 
 'Place this code in a UserForm
 'UserForm must have two command buttons (CommandButton1 & 2)
 'UserForm must have one listbox (ListBox1)
 
Option Explicit 
 
Private Sub CommandButton1_Click() 
     
    If ListBox1.Text <> "" Then 
        Workbooks.Open FileName:=Path & "\" & ListBox1.Text 
    End If 
     
    Unload Me 
     
End Sub 
 
Private Sub CommandButton2_Click() 
     
    Unload Me 
     
End Sub