'********************************
 '<< CODE FOR USERFORM MODULE >>
 
Option Explicit 
 
Private Sub UserForm_Activate() 
     
    Dim FormControl As Control, N& 
     
     '//allow form to load
    DoEvents 
     
    Application.ScreenUpdating = False 
     
     '//error = no 'SnapShot' sheet
    On Error GoTo AddSnapShot 
    Sheets("SnapShot").Activate 
     
SheetExists: 
    Cells.ClearContents 
     
     '//put column headings on the sheet
    [A1] = "Control" 
    [B1] = ".Height" 
    [C1] = ".Width" 
    [D1] = ".Top" 
    [E1] = ".Left" 
     
     '//get userform metrics
    With [A2] 
        .Offset(0, 0) = Me.Name 
        .Offset(0, 1) = Me.Height 
        .Offset(0, 2) = Me.Width 
        .Offset(0, 3) = Me.Top 
        .Offset(0, 4) = Me.Left 
        N = 1 
         
         '//get all the control metrics
        For Each FormControl In Controls 
            .Offset(N, 0) = FormControl.Name 
            .Offset(N, 1) = FormControl.Height 
            .Offset(N, 2) = FormControl.Width 
            .Offset(N, 3) = FormControl.Top 
            .Offset(N, 4) = FormControl.Left 
            N = N + 1 
        Next FormControl 
    End With 
     
     '//tart up the sheet a bit
    Rows(1).Font.Bold = True 
    Columns(1).Font.Bold = True 
    With Cells 
        .Columns.AutoFit 
        .Rows.AutoFit 
        .HorizontalAlignment = xlLeft 
    End With 
     
     '//unload the userform & exit sub
    Unload Me 
    Exit Sub 
     
AddSnapShot: '//add a sheet
    ActiveWorkbook.Sheets.Add after:=Sheets(Sheets.Count) 
    ActiveSheet.Name = "Snapshot" 
     '//clear error and start again at SheetExists
    Resume SheetExists 
End Sub 
 '********************************
 
 
 
 '********************************
 '<< CODE FOR MODULE1 >>
 
Option Explicit 
 
Sub ShowForm() 
    UserForm1.Show False 
End Sub 
 
 '********************************