Option Explicit 
 
 '  * * * * * * * * * * * * * * * * * * *
 ' Initialize and Populating Procedures
 '  * * * * * * * * * * * * * * * * * * *
Private Sub UserForm_Initialize() 
     ' hide the label that makes
     ' the form bigger (after it has been hidden)
    lblShowMe.Visible = False 
     ' populates the bookmark dropdown list
    FillBookmarkList 
End Sub 
 
Sub FillBookmarkList() 
    Dim mBookmark As Bookmark 
    On Error GoTo NoBookmarks 
     ' if there are bookmarks
     ' add the name of each one to
     ' the Bookmarks combobox
    If ActiveDocument.Bookmarks.Count > 0 Then 
        For Each mBookmark In ActiveDocument.Bookmarks() 
            cboBookmarks.AddItem mBookmark.Name 
        Next 
         ' display the first bookmark in the list
        cboBookmarks.ListIndex = 0 
        Exit Sub 
    Else 
        GoTo NoBookmarks 
    End If 
    Exit Sub 
NoBookmarks: 
     ' no bookmarks?  display that
    cboBookmarks.AddItem " no bookmarks " 
    cboBookmarks.ListIndex = 0 
End Sub 
 
Private Sub cmdGoToBookmark_Click() 
     ' moves the Selection point to
     ' just before the bookmark (if it exists)
     ' does NOT select the bookmark
     
    If BookmarkExists(cboBookmarks.Text) Then 
        With Selection 
            .GoTo what:=wdGoToBookmark, Name:=cboBookmarks.Text 
            .Collapse direction:=wdCollapseStart 
        End With 
    Else 
        MsgBox "Bookmark doesn't exists" 
    End If 
End Sub 
 
Private Sub cmdSelectBM_Click() 
     ' moves the Selection to the current bookmark (if it exists)
     ' in the combobox drop down list
     ' selects it, unloads form
    If BookmarkExists(cboBookmarks.Text) Then 
        ActiveDocument.Bookmarks(cboBookmarks.Text).Select 
        Unload Me 
    Else 
        MsgBox "Bookmark doesn't exists" 
    End If 
End Sub 
 
Private Sub cmdDeleteBM_Click() 
     ' deletes the current selected bookmark (if it exists)
     ' in the combobox dropdown list (if not a formfield)
     ' clears the list, then repopulates it
     ' does NOT close form, so multiple actions
     ' are allowed
    Dim oBookmark   As Word.Bookmark 
     
    If BookmarkExists(cboBookmarks.Text) Then 
         
        Set oBookmark = ActiveDocument.Bookmarks(cboBookmarks.Text) 
         
        If ISFormfield(oBookmark.Name) = False Then 
            oBookmark.Delete 
            cboBookmarks.Clear 
            FillBookmarkList 
        Else 
            MsgBox "Bookmark is a formfield" 
        End If 
    Else 
        MsgBox "Bookmark doesn't exists" 
    End If 
     
     'Clean up
    Set oBookmark = Nothing 
End Sub 
 
Private Sub cmdAddBookmark_Click() 
     ' warns if you add a bookmark name that allready exists
     ' adds a bookmark at the current selection
     ' point, using a name entered by user
     ' clears the combobox dropdown list
     ' then repopulates it
     ' does NOT close form, so multiple selections
     ' added as bookmarks are allowed
    If txtNewBMName.Text = "" Then 
        MsgBox "You must have a name for a new bookmark.  " & _ 
        "Please type a name in the New Bookmark Name field." 
        txtNewBMName.SetFocus 
        Exit Sub 
    Else 
        If BookmarkExists(txtNewBMName.Text) Then 
            MsgBox "This bookmark allready exists" 
        Else 
            ActiveDocument.Bookmarks.Add Range:=Selection.Range, _ 
            Name:=txtNewBMName.Text 
            cboBookmarks.Clear 
            FillBookmarkList 
            txtNewBMName.Text = "" 
        End If 
    End If 
End Sub 
 ' * * * * * * * * * * * * * * * * * * *
 ' Hiding and Showing Procedures
 ' * * * * * * * * * * * * * * * * * * *
Private Sub cmdHide_Click() 
     ' resize the form smaller, showing
     ' just the form title bar and label
     ' that fires the resize back to full size
     ' also moves it to the top of the screen
     ' this can be adjusted for various
     ' resolutions if needed
    With frmBookmarks 
        .Height = 35 
        .Width = 130 
        .Top = 0 
        .Left = 300 
    End With 
     ' display the label that resizes back
     ' to full size.  Label Click and DblClick
     ' events fire the resize procedure MakeBigger
    lblShowMe.Visible = True 
End Sub 
 
Private Sub lblShowMe_Click() 
     ' does nothing if the full form is visible
     ' otherwise, makes form full size
    If frmBookmarks.Height = 166 Then 
        Exit Sub 
    Else 
        MakeBigger 
    End If 
End Sub 
 
Private Sub lblShowMe_DblClick(ByVal Cancel As MSForms.ReturnBoolean) 
     ' does nothing if the full form is visible
     ' otherwise, makes form full size
    If frmBookmarks.Height = 166 Then 
        Exit Sub 
    Else 
        MakeBigger 
    End If 
End Sub 
 
 
Sub MakeBigger() 
     ' resizes form to full size
     ' positions it back to center screen
    With frmBookmarks 
        .Height = 166 
        .Width = 225 
        .StartUpPosition = 1 
        .Show 
    End With 
     ' hide the label that fires MakeBigger
    lblShowMe.Visible = False 
End Sub 
 
Private Sub cmdDone_Click() 
     ' closes the form
    Unload Me 
End Sub 
 
 ' * * * * * * * * * * * * * * * * * * *
 ' Bookmark/Formfield support functions
 ' * * * * * * * * * * * * * * * * * * *
Public Function BookmarkExists(sBookmark As String) As Boolean 
     'Checks if a bookmark exists in the active document
    If ActiveDocument.Bookmarks.Exists(sBookmark) Then 
        BookmarkExists = True 
    Else 
        BookmarkExists = False 
    End If 
End Function 
 
Public Function ISFormfield(sName As String) As Boolean 
    Dim oFormField  As Word.FormField 
     'Checks if bookmark IS a formfield
    If ActiveDocument.FormFields.Count = 0 Then 
        ISFormfield = False 
    Else 
        For Each oFormField In ActiveDocument.FormFields() 
            If oFormField.Name = sName Then 
                ISFormfield = True 
            End If 
        Next 
    End If 
End Function