Option Explicit 
 
Function GetOpenFilenameFrom(Optional sDirDefault As String) As Variant 
     'Macro Purpose: To ask for a file at a specified directory
     'Returns either the full path including the filename,
     'or False if nothing selected
     
    Dim sDirCurrent As String, _ 
    sFileTypes As String 
     
     'Set the file types desired to show in the dialog box
    sFileTypes = "All Files (*.*),*.*" 
     
     'For specific file types, comment the line above, uncomment & adjust the line below
     'Help on the exact syntax can be found by looking up the GetOpenFilename method in
     'the VBA help files
     'sFileTypes = "Excel Worksheets (*.xls), *.xls,Word Documents (*.doc), *.doc," _
    & "All Files (*.*),*.*" 
     
     'Make note of the current directory
    sDirCurrent = CurDir 
     
    If sDirDefault = vbNullString Then 
         'If optional arguement not supplied then
         'assign current directory as default
        sDirDefault = CurDir 
    Else 
         'If option arguement is supplied, test path to ensure
         'that it exists.  If not, assign current directory
        If Len(Dir(sDirDefault, vbDirectory)) = 0 Then 
            sDirDefault = sDirCurrent 
        End If 
    End If 
     
     'Change the drive and directory
     '*Drive change is unecessary if same, but takes as long to test
     ' as just changing it
    ChDrive Left(sDirDefault, 1) 
    ChDir (sDirDefault) 
     
     'Get the file's name & path
    GetOpenFilenameFrom = Application.GetOpenFilename(sFileTypes) 
     
     'Change the drive and directory back
    ChDrive Left(sDirCurrent, 1) 
    ChDir (sDirCurrent) 
     
End Function 
 
Sub Test() 
     'Macro Purpose:  To test the GetOpenFilenameFrom function
    Dim sWBToOpen As Variant 
    sWBToOpen = GetOpenFilenameFrom(Range("A3").Value) 
     
    If Not sWBToOpen = False Then Workbooks.Open (sWBToOpen) 
     
End Sub