Option Explicit 
 
Sub CopyChartsToNewBookAndDelinkThemToo() 
    Dim Cht As Chart 
    Dim oSeries As Series 
    Dim wks As Worksheet 
    Dim szNewFile As String 
     
     '   Do we have any charts?
    If ActiveWorkbook.Charts.Count > 0 Then 
         
         '   if yes:
         '   No screen flicker, or new workbook appearance:
        With Application 
            .ScreenUpdating = False 
            If Val(.Version) >= 9 Then 
                .ShowWindowsInTaskbar = False 
            End If 
             
             
            On Error GoTo ErrHandle 
             '       This copies the charts all to a new workbook
             '       The new workbook becomes the active workbook
             '       *Amended by Jon Peltier
            ActiveWorkbook.Charts.Copy 
             
             
             
             '       Delink all the charts from the original workbook
            For Each Cht In ActiveWorkbook.Charts 
                For Each oSeries In Cht.SeriesCollection 
                    With oSeries 
                        .Name = .Name 
                        .Values = .Values 
                        .XValues = .XValues 
                    End With 
                Next 
            Next 
             
             
             
             '       Where and under what name to store our new workbook of charts
             '       Initial file name is [BookOCharts], user changes to suit
            szNewFile = .GetSaveAsFilename("BookOCharts.xls", _ 
            "Excel Files (*.xls), *.xls") 
             
             
            With ActiveWorkbook 
                 
                If szNewFile <> "False" Then 
                     
                     '                Save it and close it
                    .SaveAs szNewFile 
                    .Close 
                     
                Else 
                     
                     '                if it was canceled
                    .Close False 
                     
                End If 
                 
            End With 
             
             
ErrExit: 
            If Val(.Version) >= 9 Then 
                .ShowWindowsInTaskbar = True 
            End If 
            .ScreenUpdating = True 
        End With 
         
         
    Else 
         
        MsgBox "No chart sheets are available to copy", 64 
         
    End If 
    Exit Sub 
     
     
ErrHandle: 
    MsgBox Err.Description 
    GoTo ErrExit 
End Sub