Option Explicit 
Private Sub Worksheet_Change(ByVal Target As Range) 
     
     'Simple error handling, but effective.
On Error GoTo MyHandler: 
     
     'If the range of Target is more than one cell, this will error
     'unless this only runs if there is only one member of the range.
    If Target.Count = 1 Then 
         
         'IsNumeric will check that the entry can be evaluated as a number.
         'Also, this code is set for RGB and HEX
         'so it will only evaluate a number between 0 and 255.
        If IsNumeric(Target) And Target <= 255 And Target >= 0 Then 
             
             'Always a good idea to turn off events during a change event
             'so that the event doesn't run during the execution of this code.
            Application.EnableEvents = False 
             
             'Make the change in the adjecent cell.
            With Target.Offset(, 1) 
                 'Change the cell format to text so the possible leading zero will display.
                .NumberFormat = "@" 
                 
                 'Text is aligned left, I like right aligned better.
                .HorizontalAlignment = xlRight 
                 
                 'This uses the native VBA function Hex() to evaluate the entered number.
                .Value = Hex(Target) 
            End With 
             
             'However, I want the leading zero to display.
            If Len(Target.Offset(, 1)) = 1 Then 
                Target.Offset(, 1) = "0" & Hex(Target) 
            End If 
             
             'Remember to turn events back on.
            Application.EnableEvents = True 
        End If 
    End If 
    Exit Sub 
     
     'Like I said, it's simple but effective error handling.
     'Since this code only changes the value of one cell,
     'there's not much trouble that an error could cause.
MyHandler: 
    Err.Clear 
     'If the error occurs after events were turned off, you will want to make sure
     'Events are turned back on.
    Application.EnableEvents = True 
End Sub