Option Explicit 
Public Sub RGB2Hex() 
     
     'Always include error handling.
On Error GoTo MyHandler: 
     
     'The rgb numbers represented by i
    Dim i As Integer 
     
     'This will hold the Hex code.
    Dim Output As String 
     
     'First we ask if you want to continue, since the code will take two rows
     'of your sheet, and overwrite anything currently there.
    Dim YN As Byte 
    YN = MsgBox("This will take up two full rows on your worksheet." & vbCrLf & _ 
    "Do you want to continue?", vbYesNo, "RGB & HEX") 
     
     'If you don't say Yes, the code will exit. (Yes = 6)
    If Not YN = 6 Then Exit Sub 
     
     'This error handling is to make sure you enter a number in the InputBox below.
On Error GoTo NotANumber: 
     
     'The program asks which row you would like the codes to be placed.
    Dim whereStart As Long 
    whereStart = InputBox("In which row would you like the series to start?", "RGB & HEX") 
     
     'The number must be between 1 & 65,535
     'since there are a finite number of rows on a sheet
If whereStart < 1 Or whereStart > 65535 Then GoTo NotANumber: 
     
     'If we've made it this far without a number error, we can go back
     'to using the simple error handler.
On Error GoTo MyHandler: 
     
     'Since HEX codes for colors are two digits, this returns some numbers with
     'leading zeroes.  Excel thinks that's a problem, but it isn't.
     'This will turn off the Error Checking for a number stored as text.
    Application.ErrorCheckingOptions.NumberAsText = False 
     
     'Loop through the RGB numbers 0 to 255.
    For i = 0 To 255 
         
         'The first row is the RGB number.
        With Cells(whereStart, i + 1) 
            .Value = i 
             
             'It looks nice centered.
            .HorizontalAlignment = xlCenter 
        End With 
         
         'Use the native function to find the HEX code.
        Output = Hex(i) 
         
         'Now find those numbers that need the leading zero.
        If Len(Output) = 1 Then Output = "0" & Output 
         
        With Cells(whereStart + 1, i + 1) 
             'Format the second row as text to return a leading zero when needed.
            .NumberFormat = "@" 
             
             'Set the cell to Output.
            .Value = Output 
             
             'I still think it looks better centered.
            .HorizontalAlignment = xlCenter 
        End With 
    Next 
    Exit Sub 
     
     'Handling the number issues.
NotANumber: 
    Err.Clear 
    MsgBox "You must enter a number between 1 and 65,535", vbOKOnly, "Enter a number" 
    Exit Sub 
     
     'Handling anything else that might crop up.
MyHandler: 
    MsgBox Err.Description 
    Err.Clear 
End Sub