Option Explicit 
Sub tester() 
     'testing sub - this code is NOT required to run the function - it only
     'demonstrates the function in operation
    Dim s As String 
    s = "500 in base..." & vbCr & "16 is " & Base2Dec("500", 16) & " in Decimal" & vbCr & _ 
    "8 is " & Base2Dec("500", 8) & " in Decimal" & vbCr & _ 
    "13 is " & Base2Dec("500", 13) & " in Decimal" 
    MsgBox s 
End Sub 
 
Public Function Base2Dec(ByVal BaseVal As String, ByVal base As Long) As Variant 
     'converts a string representation of a number in base(base) to the equivalent in decimal
     '(base 2 to base 16).  Base needs to be specified as decimal ie
     '8 for base 8, 16 for base 16, 2 for base 2 etc
    Static Digits 
    Dim i As Long, sTemp As String, lVal As Long 
     'check valid base:
    If base < 2 Or base > 16 Then Base2Dec = "Invalid base used": Exit Function 
    On Error GoTo err_handler 
    If IsEmpty(Digits) Then _ 
    Digits = VBA.Array("0", "1", "2", "3", "4", "5", "6", "7", "8", "9", "A", "B", "C", "D", "E", "F") 
    sTemp = UCase(BaseVal) 
    lVal = 0 
     'generate decimal values of BaseVal digits:
    For i = Len(BaseVal) To 1 Step -1 
        lVal = lVal + (WorksheetFunction.Match(Mid$(BaseVal, i, 1), Digits, False) - 1) * (base ^ (Len(BaseVal) - i)) 
    Next i 
     'output:
    Base2Dec = lVal: Exit Function 
err_handler: 
    Base2Dec = "Error" 
End Function